AC_INIT([cl-darcs], [0.3.0], [cl-darcs-devel@common-lisp.net])
AM_INIT_AUTOMAKE([no-dependencies foreign])

my_lisp=""

AC_ARG_WITH(clisp, [AS_HELP_STRING([--with-clisp], [use clisp])],
		   [my_lisp=$my_lisp"clisp"], [])
AC_ARG_WITH(clisp-flags, [AS_HELP_STRING([--with-clisp-flags], [clisp flags (default -i ~/.clisprc)])],
			 [],
			 [with_clisp_flags="-i ~/.clisprc"])

AC_ARG_WITH(sbcl, [AS_HELP_STRING([--with-sbcl], [use sbcl])],
		  [my_lisp=$my_lisp"sbcl"], [])
AC_ARG_WITH(sbcl-flags, [AS_HELP_STRING([--with-sbcl-flags], [sbcl flags (default --disable-debugger)])],
			[],
			[with_sbcl_flags="--disable-debugger"])

dnl First, try to find clisp
if test -z "$my_lisp" -o "$my_lisp" = clisp; then
  if test -z "$CLISP"; then
    AC_CHECK_PROG(CLISP, clisp, clisp, [])
  fi
  if test -n "$CLISP"; then
    my_lisp=clisp
    AC_MSG_CHECKING([for clisp flags])
    CLISP_FLAGS=$with_clisp_flags
    AC_MSG_RESULT($CLISP_FLAGS)
  fi
fi

dnl Then, try to find sbcl
if test -z "$my_lisp" -o "$my_lisp" = sbcl; then
  if test -z "$SBCL"; then
    AC_CHECK_PROG(SBCL, sbcl, sbcl, [])
  fi
  if test -n "$SBCL"; then
    my_lisp=sbcl
    AC_MSG_CHECKING([for sbcl flags])
    SBCL_FLAGS=$with_sbcl_flags
    AC_MSG_RESULT($SBCL_FLAGS)
  fi
fi

dnl Did we find any lisp?
if test -z "$my_lisp"; then
  AC_MSG_ERROR([no lisp found])
fi

AC_SUBST(my_lisp)
AC_SUBST(CLISP)
AC_SUBST(CLISP_FLAGS)
AC_SUBST(SBCL)
AC_SUBST(SBCL_FLAGS)

AC_CONFIG_FILES([Makefile])
AC_OUTPUT